REM Flags: Flag 1 standing in busy street
REM        Flag 2 Has given cola to girl
REM        Flag 3 Has given right locket to girl
REM        Flag 4 Only get points first time in bedroom


COMMAND ANY
  AtLocation 31
  FlagON 1
  AddToVariable 1 1
  VariableGT 1 1
  PrintMessage 105 (*car runs over you *)
  KillPlayer
  EndGame
  DoneWithTurn
END_COMMAND

COMMAND RAPE ANY
  Present 201
  PrintMessage 190 (*dirty pig, don't want you in my game*)
  KillPlayer
  EndGame
  DoneWithTurn
END_COMMAND

COMMAND ANY
  AtLocation 31  (*middle of busy street!*)
  FlagOFF 1
  TurnFlagON 1
END_COMMAND

COMMAND ANY
  AtLocation 3 (* Susan's Front Room *)
  IsSomewhere 201 (* she's gotta be somewhere *)
  PutInCurrentRoom 201 (* make sure she's where she belongs *)
END_COMMAND

COMMAND ANY
  AtLocation 4 (* Susan's Bedroom *)
  IsSomewhere 201 (* she's gotta be somewhere *)
  PutInCurrentRoom 201 (* no good being there without her *)
END_COMMAND

COMMAND KISS TRAMP
  Present 201
  PrintMessage 106
  DoneWithTurn
END_COMMAND

COMMAND KISS GIRLFRIEND
  AtLocation 3 (* Susan's Front Room *)
  FlagOFF 2 (* hasn't given her a cola yet *)
  PrintMessage 9 (* Mouth is too dry to smooch now *)
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND GIVE COLA
  AtLocation 3 (* Susan's Front Room *)
  IsCarrying 213 (*gotta have cola to give *)
  PrintMessage 8 (* ah, that hits the spot *)
  TurnFlagON 2   (* Comment Censored *)
  Destroy 213
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND GIVE COLA
  PrintMessage 101
  LookAtRoom
  ShowInventory
  DoneWithTurn
END_COMMAND

COMMAND KISS GIRLFRIEND
  AtLocation 3 (*Susan's Front Room*)
  FlagON 2 (* has given her a cola *)
  FlagOFF 4 (*hasn't done this before *)
  TurnFlagON 4 (*only gives points once *)
  GoToRoom 4 (*Susan's Bedroom*)
  PrintMessage 10
  PlusScore 20
  DoneWithTurn
END_COMMAND

COMMAND KISS GIRLFRIEND
  AtLocation 3 (*Susan's Front Room*)
  FlagON 2 (* has given her a cola *)
  FlagON 4 (*has done this before *)
  GoToRoom 4 (*Susan's Bedroom*)
  PrintMessage 10
  DoneWithTurn
END_COMMAND


COMMAND KISS GIRLFRIEND
  AtLocation 4 (*Susan's Bedroom*)
  FlagON 3 (*has given her locket *)
  IsWearing 210 (* Wearing Condom *)
  PlusScore 20
  GoToRoom 5 (* Post-Coital Bliss! *)
  PrintMessage 20 (* Comment Censored *)
  Tone 440 500
  DoneWithTurn
END_COMMAND

COMMAND KISS GIRLFRIEND
  AtLocation 4 (*Susan's Bedroom*)
  IsWearing 210 (* Wearing Condom *)
  FlagOFF 3 (*hasn't given her the locket *)
  PrintMessage 120 (* She's too upset cause she lost her locket *)
  DoneWithTurn
END_COMMAND

COMMAND GIVE LOCKET
  Present 201 (*Susan's gotta be here *)
  Present 282 (*gotta have the RIGHT locket! *)
  TurnFlagON 3
  DropIt 282
  PlusScore 20
  DoneWithTurn
END_COMMAND

COMMAND GIVE LOCKET
  Present 201
  NOUNPresent
  DropNOUN
  PrintMessage 121
  DoneWithTurn
END_COMMAND

COMMAND BUY ANY
 Present 206
 AtLocation 41
 GetNOUN
 PlusScore 20
 Destroy 206
 DoneWithTurn
END_COMMAND

COMMAND BUY ANY
 AtLocation 41
 Present 286
 PrintMessage 122
 DoneWithTurn
END_COMMAND

COMMAND BUY ANY
  NOT Present 206
  NOT Present 286
 PrintMessage 123
 DoneWithTurn
END_COMMAND


COMMAND KISS GIRLFRIEND
  AtLocation 4 (* Susan's Bedroom *)
  PrintMessage 30  (* Comment Censored *)
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND KISS GIRLFRIEND
  PrintMessage 40  (* she ain't here, stupid! *)
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND BUY CONDOM
  AtLocation 33 (* Better be in the Drugstore *)
  IsCarrying 286 (* gotta have money to buy *)
  SendToRoom 210 1 (*give condom to player *)
  SwapLocations 286 206 (*you get change  *)
  PrintMessage 50
  PlusScore 10
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND BUY CONDOM
  AtLocation 33 (* at drugstore *)
  PrintMessage 51 (* gotta have money to buy *)
  LookAtRoom
  ShowInventory
  DoneWithTurn
END_COMMAND

COMMAND BUY CONDOM
  PrintMessage 52  (* only sold in drugstores ... *)
  DoneWithTurn
END_COMMAND

COMMAND LIFT TIMBER
  AtLocation 24
  IsCarrying 208 (* crowbar, that stuff is heavy *)
  PrintMessage 60
  GoToRoom 27 (* location 24 with timber moved *)
  PlusScore 10
  DoneWithTurn
END_COMMAND

COMMAND LIFT TIMBER
  AtLocation 24
  NOT IsCarrying 208 (* crowbar *)
  PrintMessage 61 (* too heavy to lift *)
  DoneWithTurn
END_COMMAND

COMMAND LIFT TIMBER
  NOT AtLocation 24
  PrintMessage 62 (* The Lumber cannot be moved *)
  DoneWithTurn
END_COMMAND

COMMAND OPEN DUMPSTER
  AtLocation 12
  Present 207
  IsNowhere 208
  SwapLocations 207 216
  PutInCurrentRoom 208
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND OPEN DUMPSTER
  AtLocation 12
  Present 207
  SwapLocations 207 216
  LookAtRoom
  DoneWithTurn
END_COMMAND


COMMAND OPEN DUMPSTER
  AtLocation 12
  NOT Present 207
  PrintMessage 90 (*already open *)
  DoneWithTurn
END_COMMAND

COMMAND CLOSE DUMPSTER
  AtLocation 12
  Present 216
  SwapLocations 216 207
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND CLOSE DUMPSTER
  AtLocation 12
  Present 207
  PrintMessage 92 (* already closed *)
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND CLOSE DUMPSTER
  PrintMessage 91
  DoneWithTurn
END_COMMAND

COMMAND OPEN DUMPSTER
  PrintMessage 91 (*Don't see any dumpster*)
  DoneWithTurn
END_COMMAND

COMMAND OPEN DRESSER
  Present 211
  IsNowhere 209
  SwapLocations 211 217
  PutInCurrentRoom 209 (*Flashlight *)
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND OPEN DRESSER
  Present 211
  SwapLocations 211 217
  DoneWithTurn
END_COMMAND


COMMAND OPEN DRESSER
  NOT Present 211
  PrintMessage 100  (* don't see any dresser *)
  DoneWithTurn
END_COMMAND

COMMAND CLOSE DRESSER
  Present 217
  SwapLocations 217 211
  DoneWithTurn
END_COMMAND

COMMAND OPEN REFRIGERATOR
  Present 214
  IsNowhere 213
  SwapLocations 214 215
  PutInCurrentRoom 213
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND OPEN REFRIGERATOR
  Present 214
  SwapLocations 214 215
  LookAtRoom
  DoneWithTurn
END_COMMAND


COMMAND CLOSE REFRIGERATOR
  Present 215
  SwapLocations 215 214
  LookAtRoom
  DoneWithTurn
END_COMMAND

COMMAND OPEN WALLET
  Present 202
  OpenIt 202
  ShowInventory
  DoneWithTurn
END_COMMAND
